TPTP Problem File: GEG005^1.p

View Solutions - Solve Problem

%------------------------------------------------------------------------------
% File     : GEG005^1 : TPTP v7.1.0. Released v4.1.0.
% Domain   : Geography
% Problem  : Catalunya is not part of Paris
% Version  : [RCC92] axioms.
% English  : 

% Refs     : [RCC92] Randell et al. (1992), A Spatial Logic Based on Region
%          : [Ben10a] Benzmueller (2010), Email to Geoff Sutcliffe
%          : [Ben10b] Benzmueller (2010), Simple Type Theory as a Framework
% Source   : [Ben10a]
% Names    : Problem 64 [Ben10b]

% Status   : Theorem
% Rating   : 0.12 v7.1.0, 0.38 v7.0.0, 0.29 v6.4.0, 0.33 v6.3.0, 0.40 v6.2.0, 0.43 v5.5.0, 0.33 v5.4.0, 0.60 v5.1.0, 0.80 v5.0.0, 0.60 v4.1.0
% Syntax   : Number of formulae    :   98 (   0 unit;  49 type;  40 defn)
%            Number of atoms       :  360 (  45 equality; 182 variable)
%            Maximal formula depth :   11 (   6 average)
%            Number of connectives :  232 (  11   ~;   4   |;  18   &; 189   @)
%                                         (   0 <=>;  10  =>;   0  <=;   0 <~>)
%                                         (   0  ~|;   0  ~&)
%            Number of type conns  :  195 ( 195   >;   0   *;   0   +;   0  <<)
%            Number of symbols     :   53 (  49   :;   0   =)
%            Number of variables   :  116 (   7 sgn;  33   !;   9   ?;  74   ^)
%                                         ( 116   :;   0  !>;   0  ?*)
%                                         (   0  @-;   0  @+)
% SPC      : TH0_THM_EQU_NAR

% Comments : 
%------------------------------------------------------------------------------
%----Include Region Connection Calculus axioms
include('Axioms/LCL013^0.ax').
include('Axioms/LCL014^0.ax').
%------------------------------------------------------------------------------
thf(catalunya,type,(
    catalunya: reg )).

thf(france,type,(
    france: reg )).

thf(spain,type,(
    spain: reg )).

thf(paris,type,(
    paris: reg )).

thf(a,type,(
    a: $i > $i > $o )).

thf(fool,type,(
    fool: $i > $i > $o )).

thf(t_axiom_for_fool,axiom,
    ( mvalid
    @ ( mforall_prop
      @ ^ [A: $i > $o] :
          ( mimplies @ ( mbox @ fool @ A ) @ A ) ) )).

thf(k_axiom_for_fool,axiom,
    ( mvalid
    @ ( mforall_prop
      @ ^ [A: $i > $o] :
          ( mimplies @ ( mbox @ fool @ A ) @ ( mbox @ fool @ ( mbox @ fool @ A ) ) ) ) )).

thf(i_axiom_for_fool_a,axiom,
    ( mvalid
    @ ( mforall_prop
      @ ^ [Phi: $i > $o] :
          ( mimplies @ ( mbox @ fool @ Phi ) @ ( mbox @ a @ Phi ) ) ) )).

thf(ax1,axiom,
    ( mvalid
    @ ( mbox @ a
      @ ^ [X: $i] :
          ( tpp @ catalunya @ spain ) ) )).

thf(ax2,axiom,
    ( mvalid
    @ ( mbox @ fool
      @ ^ [X: $i] :
          ( ec @ spain @ france ) ) )).

thf(ax3,axiom,
    ( mvalid
    @ ( mbox @ a
      @ ^ [X: $i] :
          ( ntpp @ paris @ france ) ) )).

thf(con,conjecture,
    ( mvalid
    @ ( mbox @ a
      @ ^ [X: $i] :
          ~ ( po @ catalunya @ paris ) ) )).

%------------------------------------------------------------------------------