Testing

A Prize Winning Curie

• Name a member of the Curie family who has won two prizes

  fof(who,conjecture,
      ? [FullName,GivenName,Prize1,Prize2] :
        ( s__familyName('Curie',FullName)
        & s__hasWonPrize(FullName,Prize1)
        & s__hasWonPrize(FullName,Prize2)
        & look_different(Prize1,Prize2)
        & s__givenName(GivenName,FullName)
        & print(printall(nl,'The answer is ',GivenName,nl)) ) ).

• YAGOSUMO facts, Prolog syntactic difference
• 13 requests queued, 12 sent, 11 axioms delivered
• 11.49s (0.23s SPASS, 11.26s XDB). 60 clauses derived.

Abraham Lincoln is a Mammal

• Prove that Abraham Lincoln is a mammal

  fof(kb_SUMO_28,axiom,(
      ! [V__X,V__Y,V__Z] :
        ( ( s__instance(V__Y,s__SetOrClass)
          & s__instance(V__X,s__SetOrClass) )
       => ( ( s__subclass(V__X,V__Y)
            & s__instance(V__Z,V__X) )
         => s__instance(V__Z,V__Y) ) ) )).
  
  fof(kb_SUMO_5811,axiom,(
      s__instance(s__Mammal,s__SetOrClass) )).
  
  fof(kb_SUMO_5813,axiom,(    
      s__subclass(s__Primate,s__Mammal) )).
  
  fof(kb_SUMO_5818,axiom,(
      s__instance(s__Primate,s__SetOrClass) )).
  
  fof(kb_SUMO_5823,axiom,(
      s__subclass(s__Hominid,s__Primate) )).
  
  fof(kb_SUMO_5824,axiom,(
      s__instance(s__Hominid,s__SetOrClass) )).
  
  fof(kb_SUMO_5826,axiom,(
      s__subclass(s__Human,s__Hominid) )).
  
  fof(kb_SUMO_5836,axiom,(
      s__instance(s__Human,s__SetOrClass) )).
  
  fof(abe_mammal,conjecture,(
      s__instance(s__AbrahamLincoln,s__Mammal) )).

• YAGOSUMO facts and SUMO ontology (internal)
• 5 requests queued, 3 sent, 10 axioms delivered
• 1.22s (0.23s SPASS, 0.99s XDB). 77 clauses derived.

An Early 18th Century Composer

• Name a composer born in the first half of the 18th century

  fof(who,conjecture,
      ? [Composer,BirthDay,BirthMonth,BirthYear] :
        ( s__instance(Composer,s__Composer)
        & s__birthdate(Composer,BirthDay,BirthMonth,BirthYear)
        & $greatereq_int(BirthYear,1700)
        & $lesseq_int(BirthYear,1750)
        & print(printall(nl,'The answer is ',Composer,nl)) ) ).

• YAGOSUMO facts, Prolog arithmetic
• 1154 requests queued, 119 sent, 1163 axioms delivered
• 29.82s (27.15s SPASS, 12.67s XDB). 21217 clauses derived.

An OECD Capital at the Same Latitude as Moscow that could get Flooded

• Name an OECD country's capital that is at the same latitude as Moscow (to the nearest degree), that could get flooded

  fof(kb_SUMO_28,axiom,(
      ! [V__X,V__Y,V__Z] :
        ( ( s__instance(V__Y,s__SetOrClass)
          & s__instance(V__X,s__SetOrClass) )
       => ( ( s__subclass(V__X,V__Y)
            & s__instance(V__Z,V__X) )
         => s__instance(V__Z,V__Y) ) ) )).
  
  fof(kb_SUMO_MILO_6297,axiom,(
      s__instance(s__WaterArea,s__SetOrClass) )).
  
  fof(kb_SUMO_MILO_10029,axiom,(
      s__instance(s__BodyOfWater,s__SetOrClass) )).
  
  fof(kb_SUMO_MILO_DOMAINS_9645,axiom,(
      s__subclass(s__Sea,s__BodyOfWater) )).
  
  fof(kb_SUMO_MILO_DOMAINS_9546,axiom,(
      s__subclass(s__BodyOfWater,s__WaterArea) )).
  
  fof(kb_SUMO_MILO_DOMAINS_80407,axiom,(
      s__instance(s__Sea,s__SetOrClass) )).
  
  fof(flood_near_water,axiom,
      ! [W,C] :
        ( ( s__orientation(C,W,s__Near)
          & s__instance(W,s__WaterArea) )
       => s__capability(s__Flooding,s__located__m,C) ) ).
  
  fof(coastal_cities_near_water,axiom,
      ! [City] :
        ( s__instance_ground(City,s__CoastalCitiesClass)
       => ? [Sea] :
            ( s__instance(Sea,s__Sea)
            & s__orientation(City,Sea,s__Near) ) ) ).
  
  fof(where,conjecture,
      ? [City,Country,EnglishCity,CityLat,CityLong,CityName,CityCountry,
         RoundLat,MoscowLat,MoscowLong,MoscowName,MoscowCountry] :
        ( s__instance(Country,s__OECDMemberEconomiesClass)
        & s__capitalCity(City,Country)
        & xdb_ut(City,yagosumo,yagosumo,EnglishCity,english)
        & look_different(EnglishCity,'Moscow')
        & latlong(EnglishCity,CityLat,CityLong,CityName,CityCountry)
        & $eval_real($round_real(CityLat),RoundLat)
        & latlong('Moscow',MoscowLat,MoscowLong,MoscowName,MoscowCountry)
        & $eval_real($round_real(MoscowLat),RoundLat)
        & s__capability(s__Flooding,s__located__m,City)
        & print(printall(nl,nl,'The city is ',EnglishCity,' in ',Country,
  ' at latitude ',CityLat,' (Moscow is at ',MoscowLat,')',nl,nl)) ) ). 

• Needs preemptive requests for axioms (-EAsk=3)
• YAGOSUMO facts, Yahoo Map Services, Prolog arithmetic, Prolog syntactic difference, internal predicate proxy, XDB-universal translator, SUMO ontology (internal)
• 401 requests queued, 374 sent, 97 axioms delivered
• 25.03s (24.91s SPASS, 0.12s XDB). 10457 clauses derived.