%------------------------------------------------------------------------------
%----Mapping Mondial data to YAGOSUMO instances
fof(city_instances_by_mondial,axiom,
    ! [City,Country] :
      ( s__mondial_city(City,Country)
     => s__instance(City,s__City) ) ).

fof(meet_spatially_by_mondial,axiom,
    ! [Country1,Country2,Length] :
      ( s__mondial_countries_meet(Country1,Country2,Length)
     => s__meetsSpatially(Country1,Country2) ) ).

%----Spatially meeting nations have a nationLandPath
fof(nationLandPath,axiom,
    ! [X,Y] :
      ( ( s__meetsSpatially(X,Y)
        & s__instance_ground(X,s__Nation)
        & s__instance_ground(Y,s__Nation) )
     => nationLandPath(X,Y) ) ).

%----Geographic subregions have a regionLandPath
fof(regionLandPath,axiom,
    ! [X,Y] :
      ( s__geographicSubregion(X,Y)
     => ( subRegionLandPath(X,Y)
        & superRegionLandPath(Y,X) ) ) ).

%----Capital cities are geographic subregions
fof(kb_SUMO_MILO_DOMAINS_CACHE_206,axiom,(
    ! [V__ROW1,V__ROW2] :
      ( s__capitalCity(V__ROW1,V__ROW2)
     => s__geographicSubregion(V__ROW1,V__ROW2) ) )).

%----A subRegionLandPath+nationLandPath+subRegionLandPath make a regionLandPath
fof(nationSubregionLandPath,axiom,
    ! [Region1,Nation1,Region2,Nation2] :
      ( ( subRegionLandPath(Region1,Nation1)
        & nationLandPath(Nation1,Nation2)
        & superRegionLandPath(Nation2,Region2) )
     => regionLandPath(Region1,Region2) ) ).
 
%----Prove you can get from Vienna to Budapest
fof(vienna_budapest,conjecture,
    regionLandPath(s__Vienna,s__Budapest) ).
%------------------------------------------------------------------------------